@echo off
rem myusbonly_logonscript.bat --- release v1.05 for Windows 2000/XP/Vista/7/2003/2008
rem please run this batch as administrator user

rem ### --- MUST CHANGE - BEGIN ###
set COPY_FROM_SERVER_SHARED_PATH=\\192.168.1.1\netlogon_script
rem Note: 
rem Change value of COPY_FROM_SERVER_SHARED_PATH
rem Copy myusbonly_setup.msi, MyUSBOnly.bin, key.bin (if any) to above folder
rem MyUSBOnly.bin file is MyUSBOnly main configuration file
rem You can find it at C:\Documents and Settings\All Users\Application Data\MyUSBOnly\
set SAVE_INSTALLATION_LOGFILE=\\192.168.1.1\netlogon_script\MyUSBOnly_InstallLog.txt
set SOFTWARE_SERIAL_NUMBER=XXXXX-XXXXX
rem ### --- MUST CHANGE - END ###

rem Default values
set MYUSBONLY_INSTALLED_PATH=C:\Program Files\A.C. Element MyUSBOnly

IF NOT EXIST "%COPY_FROM_SERVER_SHARED_PATH%\reload.bin" echo 1 > "%COPY_FROM_SERVER_SHARED_PATH%\reload.bin"
echo %SOFTWARE_SERIAL_NUMBER% > "%COPY_FROM_SERVER_SHARED_PATH%\Trialsn.bin"

:install_upgrade
md "%MYUSBONLY_INSTALLED_PATH%"
rem ### Step 1: copying MyUSBOnly main configuration file (i.e. Whitelist, MyUSBOnly Password, Report Server IP¡K)
rem ### (you can use the file found in folder C:\Documents and Settings\All Users\Application Data\MyUSBOnly\MyUSBOnly.bin
rem ### from any install machine as MASTER MyUSBOnly main configuration file)
IF EXIST %COPY_FROM_SERVER_SHARED_PATH%\MyUSBOnly.bin copy %COPY_FROM_SERVER_SHARED_PATH%\MyUSBOnly.bin "%MYUSBONLY_INSTALLED_PATH%" /Y
IF EXIST %COPY_FROM_SERVER_SHARED_PATH%\MyUSBOnly.bin copy %COPY_FROM_SERVER_SHARED_PATH%\MyUSBOnly.bin "%SystemRoot%\kmuusb.sys" /Y
rem ###
rem ### Step 2: copying license key file (optional, for site license version only)
rem ### (if the software you purchase is non-site license version you requires to provide 
rem ### a SERIAL_NUMBER parameter in following .msi package to activate the software individually on each machine)
rem IF NOT EXIST %COPY_FROM_SERVER_SHARED_PATH%\key.bin copy %COPY_FROM_SERVER_SHARED_PATH%\Trialsn.bin "%MYUSBONLY_INSTALLED_PATH%" /Y
copy %COPY_FROM_SERVER_SHARED_PATH%\Trialsn.bin "%MYUSBONLY_INSTALLED_PATH%" /Y
IF EXIST %COPY_FROM_SERVER_SHARED_PATH%\key.bin copy %COPY_FROM_SERVER_SHARED_PATH%\key.bin "%MYUSBONLY_INSTALLED_PATH%" /Y
IF EXIST %COPY_FROM_SERVER_SHARED_PATH%\key.bin copy %COPY_FROM_SERVER_SHARED_PATH%\key.bin "%SystemRoot%\kmukey.sys" /Y
rem ###
rem ### Step 3: starting MyUSBOnly silent installation
rem ### (if the software you purchase is non-site license version you requires to provide 
rem ### a SERIAL_NUMBER parameter in following .msi package to activate the software individually on each machine)
msiexec /quiet /qn /i %COPY_FROM_SERVER_SHARED_PATH%\myusbonly_setup.msi ENABLE_ADMIN=1 SERIAL_NUMBER="%SOFTWARE_SERIAL_NUMBER%"
IF EXIST "%MYUSBONLY_INSTALLED_PATH%\SMSS.EXE" start "" /d"%MYUSBONLY_INSTALLED_PATH%\" /min "%MYUSBONLY_INSTALLED_PATH%\SMSS.EXE"
rem ###
rem ### Step 4: telling MyUSBOnly to reload the main configuration file immediately
copy %COPY_FROM_SERVER_SHARED_PATH%\reload.bin "%MYUSBONLY_INSTALLED_PATH%" /Y
rem ###
rem ### Step 5: cleanup
del "%COPY_FROM_SERVER_SHARED_PATH%\reload.bin"
del "%COPY_FROM_SERVER_SHARED_PATH%\Trialsn.bin"
IF EXIST "%MYUSBONLY_INSTALLED_PATH%\SMSS.EXE" (goto install_ok) else (goto install_fail)

rem ### Step 6: write the log
:install_ok
echo --- Installed/Upgrade *OK* MyUSBOnly to ---%computername%--- On %date% %time% >> %SAVE_INSTALLATION_LOGFILE%
goto final

:install_fail
echo --- Installed/Upgrade FAIL MyUSBOnly to ---%computername%--- On %date% %time% >> %SAVE_INSTALLATION_LOGFILE%
goto final

:final
exit